Normalt skall vi inte loopa genom fälten som i föregående exempel. Loopar tar tid
och oftast så vet vi ju vilka fält från databasen vi vill visa. Men även när vi använder
konstruktionen RS("FÄLTNMAMN") eller RS(indexsiffra)
så krävs en "sökning" då rätt fält skall hittas i fältkollektionen.
Genom att använda nedanstående metod så görs denna "fältsökning" bara en gång
Använder vi SELECT * FROM... kan det ju även hända att vi inte behöver alla fält som kommer
i resultattabellen.

En prestanda optimerad kod blir då: 
(Eftersom IIS kompilerar ASP koden först gången den körs så kan
koden vara lite trög första gången sidan laddas.
Nästa gång har den fått upp farten)
<div class=code>
<% 
' för att kunna mäta snabbheten så lagrar jag först nuvarande tid 
startTime = now 
%> 
 
<% 
' Deklarerar variablerna som skall användas 
Dim Conn 
Dim RS 
' Nedanstående kall användas för objekt av type Field 
Dim byteField, textField, memoField 
 
Set Conn = Server.CreateObject("ADODB.Connection") 
Conn.Open strConn 
 
' Första optimeringen - tag bara de fält vi vill ha 
Set RS = Conn.Execute("SELECT aBYTE, aTEXT, aMEMO FROM EXEMPELDATA ORDER BY aTEXT") 
 
' Andra och viktigaste optimeringen 
' Säger nedan vilket fältobjekt som är vilket fält 
' Observera att om det är objekt så måste Set användas 
' Det blir oftast STOR skillnad i fart om man använder fältobjekt 
Set byteField = RS("aBYTE") 
Set textField = RS("aTEXT") 
Set memoField = RS("aMEMO") 
%>
 
<TABLE BORDER=1> 
<TR> 
<td>aBYTE</td><td>aTEXT</td><td>aMEMO</td> 
</TR> 
<% Do While Not RS.EOF %> 
 <TR> 
 <td valign="top"> 
 <%= byteField %> 
 </td> 
 <td valign="top"> 
 <%= textField %> 
 </td> 
 <td valign="top"> 
 <%= memoField %> 
 </td> 
 </TR> 
 <% 
 RS.MoveNext 
Loop 
RS.Close 
Conn.Close 
Set RS = Nothing 
Set Conn = Nothing 
%> 
<% 
' räknar ut skillnaden mellan nu (now) och den tid vi sparade innan 
' vi startade programkoden 
="Tid i sekunder: " & DateDiff("s", startTime, now) 
%> 
</div>

Förklaring till ovanstående program:<hr>
<dl>
<dt>Set RS = Conn.Execute("SELECT aBYTE, aTEXT, aMEMO FROM EXEMPELDATA ORDER BY aTEXT")
<dd>Vi säger vilken tabell vi vill ha med hjälp av en vanlig SQL SELECT sats. Dessutom preciserar vi exakt vilka fält vi är intresserade av.
ORDER BY aTEXT gör att det sorteras enligt fältet aTEXT
<dt>Set byteField = RS("aBYTE") 
Set textField = RS("aTEXT") 
Set memoField = RS("aMEMO") 

<dd>Genom att skapa fältvariabler så söker vi fram rätt fält en
gång för alla. Om vi i en loop använder RS("aBYTE") så måste ADO för varje var söka fram det fält ti tabellen som heter aBYTE 
Nu vet den exekt vilket fält som avses och vikan då använda <%= byteField %> istället
</dl>

Resultatet av ovanstående program blir: 
<div class=res>
<% startTime = now %>

<%
' Deklarerar objekten
Dim Conn
Dim RS
Dim byteField, textField, memoField
Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open strConn
Set RS = Conn.Execute("SELECT aBYTE, aTEXT, aMEMO FROM EXEMPELDATA ORDER BY aTEXT")
Set byteField = RS("aBYTE")
Set textField = RS("aTEXT")
Set memoField = RS("aMEMO")
%>
<TABLE BORDER=1>
<TR>
<td>aBYTE</td><td>aTEXT</td><td>aMEMO</td>
</TR>
<% Do While Not RS.EOF %>
 <TR>
 <td valign="top">
 <%= byteField %>
 </td>
 <td valign="top">
 <%= textField %>
 </td>
 <td valign="top">
 <%= memoField %>
 </td>
 </TR>
 <%
 RS.MoveNext
Loop
RS.Close
Conn.Close
Set RS = Nothing
Set Conn = Nothing
%>
</table>
<% ="Tid i sekunder att utföra programmet: " & DateDiff("s", startTime, now) %>
</div>