<H4>Scribble (klotterprogram) i VB</h4>
<p>Nedan är ett program skrivet i VB, med vilket man kan klottra på skärmen.</p>
<pre>
Option Explicit
Dim isDrawing As Boolean
Dim lastX As Integer
Dim lastY As Integer

Private Sub Form_DblClick()
     Refresh
End Sub

Private Sub Form_Load()
     BackColor = vbWhite
End Sub

Private Sub Form_MouseDown(Button As Integer, _
                         Shift As Integer, _
                         X As Single, _
                         Y As Single)
     If Button = 1 Then
         ForeColor = vbBlue
     Else
         ForeColor = vbRed
     End If
     If Shift = 1 Then
         ForeColor = vbBlack
     End If
     isDrawing = True
     lastX = X
     lastY = Y
End Sub

Private Sub Form_MouseMove(Button As Integer, _
                             Shift As Integer, _
                             X As Single, _
                             Y As Single)
     If isDrawing Then
         Line (lastX, lastY)-(X, Y)
         lastX = X
         lastY = Y
     End If
End Sub

Private Sub Form_MouseUp(Button As Integer, _
                         Shift As Integer, _
                         X As Single, _
                         Y As Single)
     isDrawing = False
End Sub

</pre>
<p>Resultatet borde bli någonting i denna stil:</p>
<img src="./scribble/vbscrib.gif">