<%
Const nav_RADANTAL = 3
Const nav_SQL = "SELECT * FROM EXEMPELDATA ORDER BY aTEXT"
%>




<%
' Först en "normal" öppnade av connection o recordset
Set nav_Conn = Server.CreateObject("ADODB.Connection")
nav_Conn.Open strConn

' Kan INTE använda en Exeute för att öppna tabellen
' eftersom vi måste kunna bläddra i tabellen
' vi använder istället följande konstruktion
Set nav_RS = Server.CreateObject("ADODB.RecordSet")

' Den första ettan (1) betyder att vi öppnar tabellen som en
' KeySet. I den kan vi bläddra. Den andra ettan betyder att
' vi öppnar som ReadOnly...
nav_RS.Open nav_SQL, nav_Conn, 1, 1

' Några användbara värden
' En tabell kan hanteras i lite större block genom att
' säga att den har en PageSize (= rader per sida )
nav_RS.PageSize = nav_RADANTAL

' Vikan även kontrollera hur många sidor det blir med
' den PageSize vi gav
nav_MAX = nav_RS.PageCount

' Om det fanns ?PAGE=n på adressraden så antar vi att
' vi vill gå till sidan n
if Not IsEmpty(Request("PAGE")) Then
 ' kan väl kontollera att det var en siffra
 ' just in case...
 if IsNumeric(Request("PAGE")) Then
 nav_PAGENO = CInt(Request("PAGE"))
 Else
 ' i annat fall så får det bli sidan 1
 nav_PAGENO = 1
 End If
else
 ' första gången till sidan - ta fram rad ett
 nav_PAGENO = 1
end if

' Vi kanske är intresserade av vilken rad som är först i listan
' detta kan räknas ut på följande sätt
nav_ROW = (nav_PAGENO - 1) * nav_RADANTAL + 1

' Stöder databasen bookmark (Access borde göra detta)
harBookmark= nav_RS.Supports(8192)

If harBookmark Then
 ' gå direkt till rätt sida
 nav_RS.AbsolutePage = nav_PAGENO
Else
 ' Annars (klumpigare o långsammare)
 nav_RS.MoveFirst
 nav_RS.Move nav_PAGENO - 1
End If

%>






<table width="400" bgcolor="FFFF00" border="2"><tr>
<td width="100" align="center" bgcolor="FFFFCC">

<% IF nav_PAGENO > 1 Then %>
<a href="<% =Request.ServerVariables("URL")%>?PAGE=1">Första</a>
<% Else %>
Första
<% End If %>
</td>
<td width="100" align="center" bgcolor="FFFFCC">

<% IF nav_PAGENO > 1 Then %>
<a href="<% =Request.ServerVariables("URL")%>?PAGE=<% =nav_PAGENO - 1 %>">Föregående</a>
<% Else %>
Föregående
<% End If %>
</td>
<td width="100" align="center" bgcolor="FFFFCC">
<% If nav_PAGENO < nav_MAX Then %>
<a href="<% =Request.ServerVariables("URL")%>?PAGE=<% =nav_PAGENO + 1 %>">Nästa</a> 
<% Else %>
Nästa
<% End If %>
</td>
<td width="100" align="center" bgcolor="FFFFCC">
<% If nav_PAGENO < nav_MAX Then %>
<a href="<% =Request.ServerVariables("URL")%>?PAGE=<% =nav_MAX %>">Sista</a> 
<% Else %>
Sista
<% End If %>
</tr></table>


Sidan <% =nav_PAGENO %> av <% =nav_MAX %> 


<% For sida = 1 To nav_MAX %>
 <% if sida = nav_PAGENO Then %>
 [ <%=sida%> ]
 <% Else %>
 <a href="<% =Request.ServerVariables("URL")%>?PAGE=<% =sida %>">[ <%=sida%> ]</a>
 <% End If %>
<% Next %>
<hr>

<table border="1" cellspacing="0" cellpadding="5" width="400">


<%
raden = 0
Do While Not nav_RS.EOF And raden < nav_RADANTAL
%>


 <tr bgcolor="<% =nav_rowColor %>">
 
 <td align="right">
 <% =nav_ROW + raden %>
 </td>
 
 <td>
 <% =nav_RS("aTEXT") %>
 </td>
 </tr>



<%
 raden = raden + 1
 nav_RS.MoveNext
Loop
%>
</TABLE>





<%
nav_RS.Close
nav_Conn.Close
Set nav_RS = nothing
Set nav_Conn = nothing
%>



<%
Dim nav_ColorSwitcher
Function nav_rowColor()
 if nav_ColorSwitcher Then
 nav_rowColor = "#CCFFFF"
 Else
 nav_rowColor = "#FFFFCC"
 End If
 nav_ColorSwitcher = Not nav_ColorSwitcher
End Function
%>

<hr>
Det är inte alltid så intressant att bläddra i en LÅNG lista. För att
dela upp datat i mer "lättsvalda" delar kan man välja att visa ett fast
antal rader per sida och sedan ge bläddringsmöjligheter
För att göra detta möjligt måsta några ändringar komma in från föregående listningsexempel<ol>
<li>Vi kan inte använda connection.Execute eftersom den
skapar ett "ForwardOnly" resultat och vi behöver kunna bläddra.
<li>Vi måste säga åt Recordset objektet hur många rader det skall vara på en sida.
<li>Vi måste kunna säga åt sidan att den skall bläddra
<li>Vi måste kunna säga åt tabellen vilken sida (vilka rader) som skall visas
</ol>
Lösningarna på dessa problem är:<ol>
<li>Vi skapar ett recordset objekt med 
Set recordset = Server.CreateObject("ADODB.RecordSet") 
och använder sedan 
recordset.Open SQL SATS, Connection, 1, 1 
för att öppna en "bläddringsbar" KeySet
<li>Vi kan använda recordset.PageSize = RADANTAL för att säga
hur många rader som skall visas
<li>Vi kan sända via URL:n vilken sida som skall visas. T.ex ?PAGE=3 skall ta
fram sidan 3
<lI>Vi kan använda recordset.AbsolutePage för att ta
fram en viss sida
</ol>
Detta leder till: <ol>
<li>För att kontakta databasen och tabellen skriver vi 
<div class=code>
 

Const RADANTAL = 3 
Const SQL = "SELECT * FROM EXEMPELDATA ORDER BY aTEXT" 
 
' Först en "normal" öppnade av connection o recordset 
Set Conn = Server.CreateObject("ADODB.Connection") 
Conn.Open strConn 
 
' Kan INTE använda en Exeute för att öppna tabellen 
' eftersom vi måste kunna bläddra i tabellen 
' vi använder istället följande konstruktion 
Set RS = Server.CreateObject("ADODB.RecordSet") 
 
' Den första ettan (1) betyder att vi öppnar tabellen som en 
' KeySet. I den kan vi bläddra. Den andra ettan betyder att 
' vi öppnar som ReadOnly... 
RS.Open SQL, Conn, 1, 1 
 
' En tabell kan hanteras i lite större block genom att 
' säga att den har en PageSize (= rader per sida ) 
RS.PageSize = RADANTAL 
 
' Vikan även kontrollera hur många sidor det blir med 
' den PageSize vi gav 
MAX = RS.PageCount 
</div> 

<li>För att få sidan vi vill till på URL:n kan vi göra följande 
<div class=code>
<a href="<% =Request.ServerVariables("URL")%>?PAGE=1">Första</a> 
 
<a href="<% =Request.ServerVariables("URL")%>?PAGE= 
 <% = nuvarande sida - 1%>">Föregående</a> 
 
<a href="<% =Request.ServerVariables("URL")%>?PAGE= 
 <% = nuvarande sida + 1%>">Nästa</a> 
 
<a href="<% =Request.ServerVariables("URL")%>?PAGE= 
 <% = sista sidan%>">Sista</a> 
</div>
Istället för text i href:arna kan vi självklart lägga in bilder 
Men även följande lösning kan vara användbar för att sätta upp en länklista. 
<div class=code>
<% For sida = 1 To MAX %> 
 <% if sida = PAGENO Then %> 
 [ <%=sida%> ] 
 <% Else %> 
 <a href="<% =Request.ServerVariables("URL")%>?PAGE= 
 <% =sida %>">[ <%=sida%> ]</a> 
 <% End If %> 
<% Next %> 
</div> 
<li>För att sedan göra någonting av den PAGE=n som kommer kan vi skriva följande: 
<div class=code>
<% 
' Om det fanns ?PAGE=n på adressraden så antar vi att 
' vi vill gå till sidan n 
if Not IsEmpty(Request("PAGE")) Then 
 ' kan väl kontollera att det var en siffra 
 ' just in case... 
 if IsNumeric(Request("PAGE")) Then 
 PAGENO = CInt(Request("PAGE")) 
 Else 
 ' i annat fall så får det bli sidan 1 
 PAGENO = 1 
 End If 
else 
 ' första gången till sidan - ta fram rad ett 
 PAGENO = 1 
end if 
 
' Vi kanske är intresserade av vilken rad som är först i listan 
' detta kan räknas ut på följande sätt 
ROW = (PAGENO - 1) * RADANTAL + 1 
 
' Stöder databasen bookmark (Access borde göra detta) 
harBookmark= RS.Supports(8192) 
 
If harBookmark Then 
 ' gå direkt till rätt sida 
 RS.AbsolutePage = PAGENO 
Else 
 ' Annars (klumpigare o långsammare) 
 RS.MoveFirst 
 RS.Move PAGENO - 1 
End If 
%>
</div> 
<li>För att visa själva listningen kan man skriva följande 
<div class=code>
<table border="1" cellspacing="0" cellpadding="5" width="400"> 
<% 
raden = 0 
Do While Not RS.EOF And raden < RADANTAL 
%> 
 
 <tr> 
  
 <td align="right"> 
 <% =ROW + raden %> 
 </td> 
  
 <td> 
 <% =RS("aTEXT") %> 
 </td> 
 </tr> 
 
<% 
 raden = raden + 1 
 RS.MoveNext 
Loop 
%> 
</TABLE> 
</div>
</ol>
Koden är kanske inte optimal ur prestandasynvinkel, utan jag har försökt
göra en kod som enkelt går att modifiera för sina egna behov

Klicka på "Visa ASP koden för denna sida" länken nedan för ytterligare förklaringar