Källkoden för /anders.enges/asp/browsedb.asp

---

<!--#include file="../inc/navstuff.asp" -->
<!--  normala connection strängen -->
<!--  #include file="../inc/connection.asp" -->

<p>För att se vad som finns i tabellerna så kan du använda denna sida<br />
</p>

<form>
<!-- 
          Först en combo med tabellerna. Skulle gå att kontrollera
          från den interna tabellen MSysObjects men det kräver
          adminitrator lösenord mot mdb filen
   -->
   <select name="TABLES">
<option value="EXEMPELDATA" <%  If Request("TABLES") = "EXEMPELDATA" Then %>  selected="selected" <%  End If %>>EXEMPELDATA</option>
<option value="GUESTBOOK" <%  If Request("TABLES") = "GUESTBOOK" Then %>  selected="selected" <%  End If %>>GUESTBOOK</option>
</select>
<!--  En knapp som öppnar tabellen --> 
<input type="SUBMIT" value="Öppna tabellen" name="OPENDATABASE" /><br />
  <%
    ' om vi klickade på "Öppna tabellen" knappen kommer nedanstående att
    ' bli sant
    If Not IsEmpty(Request("OPENDATABASE")) Then
       ' skapa en SELECT sats som antingen kommer att bli
       ' SELECT * FROM EXEMPELDATA
       ' eller
       ' SELECT * FROM GUESTBOOK
       ' beroende på combons värde
       SQL = "SELECT * FROM " & Request("TABLES")
       ' Skapa en connection
       Set Conn = Server.CreateObject("ADODB.Connection")
       ' Och öppna den
       Conn.Open strConn
       ' Utför SELECT satsen och sätt resultattabellen i RS objektet
       Set RS = Conn.Execute(SQL)
       %>  Välj fälten du vill se:<br />
  <!--  För att komma ihåg vilken tabell det var så kan man använda en hidden --> 
  <input type="HIDDEN" name="TABLE" value="<%  =Request("TABLES") %>" >
  <%
        ' Loopa igenom alla fälten och skapa checkboxar fär alla
        For i = 0 to RS.Fields.Count - 1
       %>  <input type="CHECKBOX" name="FIELD" value="<%= RS(i).Name %>" checked="checked" /> <%= RS(i).Name %><br />
  <%
        Next
        ' Vi jar nu kollat vilka fält som fanns och kan stänga databasen
        Conn.Close
        Set RS = Nothing
        Set Conn = Nothing
       %> 
       <!--  En knapp som öppnar tabellens innehåll --> 
       <input type="SUBMIT" value="Visa tabellens innehåll" name="OPENTABLE" />
       <%
    ' Om vi inte hade klickat på "Öppna tabellen"
    ' så kanske vi hade klickat på "Visa tabellens innehåll"
    ElseIf Not IsEmpty(Request("OPENTABLE")) Then
       ' Räknar hur många checkboxar som var valda
       If Request.QueryString("FIELD").Count <  1 Then
          ' om inga var valda har vi ingenting att visa
          Response.Write "<br>Inga fält valda!<br>"
       Else
          ' I annat fall så börjar vi plocka i hop en SELECT sats
          SQL = "SELECT "
          ' vi loopar igenom alla valda checkboxar och sätter in dem i
          ' SELECT satsen
          For I = 1 To Request.QueryString("FIELD").Count
             SQL = SQL & "[" & Request.QueryString("FIELD")(I) &"], "
          Next
          ' det kom ett komma i slutet som inte behövs
          SQL = Left(SQL , Len(SQL) -2 )
          ' Lägger till resten av SELECT satsen
          SQL = SQL & " FROM " & Request("TABLE")
          ' Öppbar databasen
          Response.Write SQL
          Set Conn = Server.CreateObject("ADODB.Connection")
          Conn.Open strConn
          ' Skriver ut select statsen om nån är nyfiken
          ' och kör sedan SELECT satsen som vi konstruerade
          Set RS = Conn.Execute(SQL)
          %> 
          <!--  Resultatet sätts in i en tabell --> 

<table border="1">
<tr><% 
                        ' Först sätter vi in en rad med fältnamnen
                        For i = 0 to RS.Fields.Count - 1 %>
<td><b><%  = RS(i).Name %></b></td>
<%  Next %></tr>

<% 
                     ' och sedan sätter vi in allt data från alla fält i resten av tabellen
                     Do While Not RS.EOF %>
<tr><%  For i = 0 to RS.Fields.Count - 1 %>
<td valign="TOP"><%  = RS(i) %></td>
<%  Next %></tr>

<%
                     ' GLÖM ALDRIG BORT ATT GÅ TILL NÄSTA POST
                     ' Oändliga loopar är PINSAMMA (det sker en timeOut efter en stund)
                     RS.MoveNext
                  Loop
               %><!--  Avsluta tabellen dit vi satte fältvärdena --></table>

<%
       ' Städar efter oss
       RS.Close
       Conn.Close
       End If
    End If
    %><!--  Avslutar formen --></form>

<!--#include file="../inc/footer.asp" -->